Skript SUBSLX: Aufschlag / Abschlag

SALTRS: Verwaltung der Sonderfelder

Dieser Eingabepunkt betrifft die Verwaltung der Erfassungsmaskensteuerung im Verkauf. Der Eingabepunkt wird verwendet in den Maskensteuerungen für Angebote, Kontrakte, Lieferungen, Retouren und Rechnungen.

Mit dem Eingabepunkt werden die in einer spezifischen Version hinzugefügten Felder auf dieselbe Weise verwaltet wie die Standardfelder.

Der Eingabepunkt liegt in der Verarbeitung SUBSLX.

Kontext und Funktionsmodus

Maskensteuerung

Während die Aktionen CREATION, MODIF, ANNULE, LIENS, INICRE und INIMOD laufen, ist eine Maskensteuerung aktiv. Die Variable GOK wird verwendet und ausgewertet. Sie ist mit dem Wert 1 belegt. Um die Maskensteuerung zu verlassen, kann GOK auf den Wert 0 gesetzt werden.

Während die Aktion APRES_MODIF läuft, ist keine Maskensteuerung aktiv.

Protokolldatei

Es ist keine Protokolldatei geöffnet.

Unterschiedliche Anwendungsfälle

 Der Eingabepunkt wird in den Aktionen CREATION, MODIF, ANNUL, LIENS, APRES_MODIF, INICRE, INMOD über Gosub PE_SALTRS aus SUBSLX der folgenden Verarbeitungen aufgerufen:

-          SUBSLQ: Maskensteuerungen Angebote

-          SUBSLC: Maskensteuerungen Aufträge

-          SUBSLO: Maskensteuerungen Kontrakte

-          SUBSLD: Maskensteuerungen Lieferungen

-          SUBSLR: Maskensteuerungen Retouren

-          SUBSLI: Maskensteuerungen Rechnungen

Inhalt der Tabelle SALTRS

Die in der Tabelle SALTRS enthaltenen Daten betreffen die gespeicherten Erfassungsparameter des Moduls Verkauf, die per Maskensteuerung geändert werden können. Es muss eine exakte Normalisierung beachtet werden:

Zu allen in eine Maske aufgenommenen Daten müssen die entsprechenden Daten in der Tabelle SALTRS angelegt werden.

Vier verschiedenen Datentypen können hinzugefügt werden:

Verfügbare Masken

Verfügbare Variablen

Zur Definition der auszuführenden Verarbeitung stehen folgende Variablen zur Verfügung:

PACTION                  Standardaktion GOBJET führt den Aufruf durch

PVERSION                  Numerische Variable für den Inhalt von GVERSION

                   (GVERSION = "1.2.4" --> PVERSION = 124 )

FJL                  Typ Maskensteuerung (SLQ = Angebot, SLC = Aufträge, SLO =

                   Kontrakte, SLD = Lieferungen, SLR = Retouren,

                   SLI = Rechnungen).

MFROM                  Code Erfassungsmaske#

 Geöffnete Tabellen

Die Tabellen AWINDOW, AWINPAR, AREPORT, AMSK, AMSKZON, AMSKACT sowie sämtliche für die Generierung der Masken- und Verarbeitungsgenerierung notwendigen Tabellen sind geöffnet, dürfen in diesem Eingabepunkt jedoch unter keinen Umständen verändert werden.

 Beispiel für die spezifische Verwendung des Eingabepunkts

 #########################################################################

# Verarbeitung des Eingabepunkts Maskensteuerungen

# Beispiel: Hinzufügen von Daten in die Auftragsverwaltung

# - AAAA (nicht erfassbar) im Register Verwaltung   SOH1    

# - BBBB (erfassbar)     im Register Lieferung SOH2 

# - CCCC (nicht erfassbar) im Register Positionen    SOH4

# - DDDD (erfassbar)     im Register Positionen    SOH4

#########################################################################

Case ACTION

  When "SALTRS"  : Gosub SALTRS

Endcase

Return

#########################################################################

$SALTRS

Case FJL

  When "SLQ" : Gosub SALTRS_SLQ : # Maskensteuerung Angebot

  When "SLC" : Gosub SALTRS_SLC : # Maskensteuerung Aufträge

  When "SLO" : Gosub SALTRS_SLO : # Maskensteuerung Kontrakte

  When "SLD" : Gosub SALTRS_SLD : # Maskensteuerung Lieferungen

  When "SLR" : Gosub SALTRS_SLR : # Maskensteuerung Retouren

  When "SLI" : Gosub SALTRS_SLI : # Maskensteuerung Rechnungen

Endcase

Return

#------------------------------------------------------------------------

$SALTRS_SLQ

Return

#------------------------------------------------------------------------

$SALTRS_SLC

Case PACTION

  When "CREATION", "MODIF", "ANNULE","EXEBOUT","MASSE"

    If MFROM="SOH1"

      If [M:SLC5]AAAACOD = 1  TZONE(IZON)="AAAA"

                              TMOD (IZON)=3

                              IZON +=1

      Endif

    Endif

    If MFROM="SOH2"

      If [M:SLC2]BBBBCOD > 1  TZONE(IZON)="BBBB"

                              TMOD (IZON)=[M:SLC2]BBBBCOD

                              IZON +=1

      Endif

    Endif

    If MFROM="SOH4"

      If [M:SLC5]CCCCCOD = 1  TZONE(IZON)="CCCC"

                              TMOD (IZON)=3

                              IZON +=1

      Else

        ZT="CCCCSCR" : ZM="CCCC" : Gosub TABLEAU_FICHE From SUBSLX

      Endif

      If [M:SLC3]DDDDCOD > 1  TZONE(IZON)="DDDD"

                              TMOD (IZON)=[M:SLC3]DDDDCOD

                              IZON +=1

      Endif

      If [M:SLC3]DDDDCOD = 1 | [M:SLC3]DDDDCOD = 2

        ZT="DDDDSCR" : ZM="DDDD" : Gosub TABLEAU_FICHE From SUBSLX

      Endif

    Endif

  When "APRES_MODIF"        : Gosub APRES_MODIF

  When "LIENS"              : Gosub LIENS

  When "INICRE" , "INIMOD"  : Gosub INICRE

  When Default

Endcase

Return

#------------------------------------------------------------------------

$SALTRS_SLO

Return

#------------------------------------------------------------------------

$SALTRS_SLD

Return

#------------------------------------------------------------------------

$SALTRS_SLR

Return

#------------------------------------------------------------------------

$SALTRS_SLI

Return

#------------------------------------------------------------------------

$APRES_MODIF 

# gemeinsame Aktion der verschiedenen Maskensteuerungen

# nur für die Positionsdaten zu entwickelnde Aktion

Local Char PCOUZON : # V120- und V130-kompatibler Name

If PVERSION < 130  PCOUZON=zoncou

  Else             PCOUZON=COUZON

Endif

If PCOUZON = "CCCCCOD" : Gosub CCCCCOD : Endif

If PCOUZON = "DDDDCOD" : Gosub DDDDCOD : Endif

Return

#------------------------------------------------------------------------

$LIENS 

# gemeinsame Aktion der verschiedenen Maskensteuerungen

# nur für die Positionsdaten zu entwickelnde Aktion

Gosub CCCCCOD

Gosub DDDDCOD

Return

#------------------------------------------------------------------------

$INICRE 

# gemeinsame Aktion der verschiedenen Maskensteuerungen

# nur für die Positionsdaten zu entwickelnde Aktion

ZONECOD="CCCCCOD"  : Gosub INICRE_SCR From SUBSLX

ZONECOD="DDDDCOD"  : Gosub INICRE_SCR From SUBSLX

Return

#------------------------------------------------------------------------

$CCCCCOD

If dim([M]CCCCCOD)>0 & dim([M]CCCCSCR)>0

  If [M]CCCCCOD=1

     [M]CCCCSCR=1

     If !GIMPORT

       If FJL="SLC" : Affzo [M:SLC5]CCCCSCR : Grizo [M:SLC5]CCCCSCR : Endif

     Endif

  Else

     If !GIMPORT

       If FJL="SLC" : Actzo [M:SLC5]CCCCSCR : Endif

     Endif

  Endif

Endif

Return

#----

$DDDDCOD

If dim([M]DDDDCOD)>0 & dim([M]DDDDSCR)>0

  If [M]DDDDCOD=3

     [M]DDDDSCR=1

     If !GIMPORT

       If FJL="SLC" : Affzo [M:SLC3]DDDDSCR : Grizo [M:SLC3]DDDDSCR : Endif

     Endif

  Else

     If !GIMPORT

       If FJL="SLC" : Actzo [M:SLC3]DDDDSCR : Endif

     Endif

  Endif

Endif

Return

#########################################################################

SALTRSWIN: Erfassungsfenster ändern

Dieser Eingabepunkt betrifft die Verwaltung der Erfassungsmaskensteuerung im Verkauf. Der Eingabepunkt wird verwendet in den Maskensteuerungen für Angebote, Kontrakte, Lieferungen, Retouren und Rechnungen.

Mit dem Eingabepunkt kann das von der Maskensteuerung generierte Fenster verändert werden, z. B.: Löschen eines individuellen Registers.

Der Eingabepunkt liegt in der Verarbeitung SUBSLX.

Kontext und Funktionsmodus

Maskensteuerung

Eine Maskensteuerung ist aktiv. Die Variable GOK wird verwendet und ausgewertet. Sie ist mit dem Wert 1 belegt. Um die Maskensteuerung zu verlassen, kann GOK auf den Wert 0 gesetzt werden.

Protokolldatei

Es ist keine Protokolldatei geöffnet.

Unterschiedliche Anwendungsfälle

 Der Eingabepunkt wird in den Aktionen CREATION, MODIF und ANNUL der folgenden Verarbeitungen aufgerufen:

-          SUBSLQ: Maskensteuerungen Angebote

-          SUBSLC: Maskensteuerungen Aufträge

-          SUBSLO: Maskensteuerungen Kontrakte

-          SUBSLD: Maskensteuerungen Lieferungen

-          SUBSLR: Maskensteuerungen Retouren

-          SUBSLI: Maskensteuerungen Rechnungen

Verfügbare Masken

Verfügbare Variablen

Zur Definition der auszuführenden Verarbeitung stehen folgende Variablen zur Verfügung:

[F:SLT]STRTYP           Transaktionstyp

[F:SLT]STRNUM          Transaktionscode

FOBJ                            Objektname ( "SQH", "SOH", "SOR", "SDH", "SIH", "SRH" )

WINREF                        Name des Referenzfensters

                                      = "O" + Objektname ( "SQH", "SOH", "SOR", "SDH", "SIH", "SRH" )

NOMWIN                       Name des für diese Maskensteuerng generierten Fensters

                                       = "WO" + Objektname + Maskensteuerungscode 

Geöffnete Tabellen

Die Tabellen AWINDOW, AWINPAR, AREPORT, AMSK, AMSKZON, AMSKACT sowie sämtliche für die Verwaltung der Masken- und Verarbeitungsgenerierung notwendigen Tabellen sind geöffnet.