Programma SUBSLX: Transazione spese/sconti

SALTRS: Gestire dei campi specifici

Questo entry point interessa la gestione delle transazioni di inserimento delle vendite. E' comune alle transazioni di offerte, ordini, ordini aperti, consegne, resi e fatture.

Permette di gestire i campi aggiunti in specifico nello stesso modo dei campi standard.

Questo entry point è situato nel programma SUBSLX.

Contesto e modalità di funzionamento

Transazione

Nello svolgimento delle azioni CREATION, MODIF, ANNULE, LIENS, INICRE e INIMOD , c'è una transazione in corso. La variabile GOK è utilizzata e testata. E' uguale a 1. Può essere posizionata a 0 se si desidera abbandonare la transazione.

Nello svolgimento dell'azione APRES_MODIF non c'è transazione in corso.

File traccia

Non c'è file traccia aperto.

Diversi casi di chiamata

Viene chiamato nelle azioni CREATION, MODIF, ANNULE, LIENS, APRES_MODIF, INICRE, INIMOD  tramite  Gosub PE_SALTRS From SUBSLX nei programmi:

-          SUBSLQ: transazioni offerte

-          SUBSLC: transazioni ordini

-          SUBSLO: transazioni ordini aperti

-          SUBSLD: transazioni consegne

-          SUBSLR: transazioni resi

-          SUBSLI: transazioni fatture

Richiamo del contenuto della tabella SALTRS

I dati contenuti nella tabella SALTRS riguardano la memorizzazione della parametrizzazione degli inserimenti del modulo vendite modificabili tramite transazioni. Deve essere rispettata una normalizzazione precisa.

Ad un dato aggiunto in una videata deve corrispondere la creazione di dati nella tabella SALTRS.

I dati aggiunti possono essere di 4 tipi diversi.

Videate disponibili

Variabili disponibili

Si dispone delle seguenti variabili per definire l'elaborazione da effettuare:

PACTION                  Azione standard GOBJET all'origine della chiamata

PVERSION                  Variabile numerica del contenuto di GVERSION

                   ( se GVERSION="1.2.4" a PVERSION=124 )

FJL                  Tipo di transazione ( SLQ= Offerte, SLC= Ordini, SLO=

                   Ordini aperti, SLD= Consegne, SLR= Resi,

                   SLI= Fatture).

MFROM                  Codice videata di inserimento

Tabelle aperte 

Le tabelle AWINDOW, AWINPAR, AREPORT, AMSK, AMSKZON, AMSKACT, così come tutte le tabelle necessarie alla gestione della generazione di videate e programmi sono aperte ma non devono in nessun caso essere modificate nel programma dell'entry point.

Esempio di programma specifico dell'entry point

 #########################################################################

# Programma dell'entry point delle transazioni

# Esempio: Aggiunta dei dati nella gestione degli ordini

# - AAAA (non inseribile) nel Folder Gestione   SOH1    

# - BBBB (inseribile)     nel Folder Consegna SOH2 

# - CCCC (non inseribile) nel Folder Righe    SOH4

# - DDDD (inseribile)     nel Folder Righe    SOH4

#########################################################################

Case ACTION

  When "SALTRS"  : Gosub SALTRS

Endcase

Return

#########################################################################

$SALTRS

Case FJL

  When "SLQ" : Gosub SALTRS_SLQ : # transazione offerte

  When "SLC" : Gosub SALTRS_SLC : # transazione ordini

  When "SLO" : Gosub SALTRS_SLO : # transazione ordini aperti

  When "SLD" : Gosub SALTRS_SLD : # transazione consegne

  When "SLR" : Gosub SALTRS_SLR : # transazione resi

  When "SLI" : Gosub SALTRS_SLI : # transazione fatture

Endcase

Return

#------------------------------------------------------------------------

$SALTRS_SLQ

Return

#------------------------------------------------------------------------

$SALTRS_SLC

Case PACTION

  When "CREATION", "MODIF", "ANNULE","EXEBOUT","MASSE"

    If MFROM="SOH1"

      If [M:SLC5]AAAACOD = 1  TZONE(IZON)="AAAA"

                              TMOD (IZON)=3

                              IZON +=1

      Endif

    Endif

    If MFROM="SOH2"

      If [M:SLC2]BBBBCOD > 1  TZONE(IZON)="BBBB"

                              TMOD (IZON)=[M:SLC2]BBBBCOD

                              IZON +=1

      Endif

    Endif

    If MFROM="SOH4"

      If [M:SLC5]CCCCCOD = 1  TZONE(IZON)="CCCC"

                              TMOD (IZON)=3

                              IZON +=1

      Else

        ZT="CCCCSCR" : ZM="CCCC" : Gosub TABLEAU_FICHE From SUBSLX

      Endif

      If [M:SLC3]DDDDCOD > 1  TZONE(IZON)="DDDD"

                              TMOD (IZON)=[M:SLC3]DDDDCOD

                              IZON +=1

      Endif

      If [M:SLC3]DDDDCOD = 1 | [M:SLC3]DDDDCOD = 2

        ZT="DDDDSCR" : ZM="DDDD" : Gosub TABLEAU_FICHE From SUBSLX

      Endif

    Endif

  When "APRES_MODIF"        : Gosub APRES_MODIF

  When "LIENS"              : Gosub LIENS

  When "INICRE" , "INIMOD"  : Gosub INICRE

  When Default

Endcase

Return

#------------------------------------------------------------------------

$SALTRS_SLO

Return

#------------------------------------------------------------------------

$SALTRS_SLD

Return

#------------------------------------------------------------------------

$SALTRS_SLR

Return

#------------------------------------------------------------------------

$SALTRS_SLI

Return

#------------------------------------------------------------------------

$APRES_MODIF 

# azione comune alle differenti transazioni

# azione da sviluppare solo per i dati di riga

Local Char PCOUZON : # per memorizzare il nome compatibile V120 e V130

If PVERSION < 130  PCOUZON=zoncou

  Else             PCOUZON=COUZON

Endif

If PCOUZON = "CCCCCOD" : Gosub CCCCCOD : Endif

If PCOUZON = "DDDDCOD" : Gosub DDDDCOD : Endif

Return

#------------------------------------------------------------------------

$LIENS 

# azione comune alle differenti transazioni

# azione da sviluppare solo per i dati di riga

Gosub CCCCCOD

Gosub DDDDCOD

Return

#------------------------------------------------------------------------

$INICRE 

# azione comune alle differenti transazioni

# azione da sviluppare solo per i dati di riga

ZONECOD="CCCCCOD"  : Gosub INICRE_SCR From SUBSLX

ZONECOD="DDDDCOD"  : Gosub INICRE_SCR From SUBSLX

Return

#------------------------------------------------------------------------

$CCCCCOD

If dim([M]CCCCCOD)>0 & dim([M]CCCCSCR)>0

  If [M]CCCCCOD=1

     [M]CCCCSCR=1

     If !GIMPORT

       If FJL="SLC" : Affzo [M:SLC5]CCCCSCR : Grizo [M:SLC5]CCCCSCR : Endif

     Endif

  Else

     If !GIMPORT

       If FJL="SLC" : Actzo [M:SLC5]CCCCSCR : Endif

     Endif

  Endif

Endif

Return

#----

$DDDDCOD

If dim([M]DDDDCOD)>0 & dim([M]DDDDSCR)>0

  If [M]DDDDCOD=3

     [M]DDDDSCR=1

     If !GIMPORT

       If FJL="SLC" : Affzo [M:SLC3]DDDDSCR : Grizo [M:SLC3]DDDDSCR : Endif

     Endif

  Else

     If !GIMPORT

       If FJL="SLC" : Actzo [M:SLC3]DDDDSCR : Endif

     Endif

  Endif

Endif

Return

#########################################################################

SALTRSWIN: Modificare la finestra di inserimento

Questo entry point riguarda la gestione delle transazioni di inserimento delle vendite. E' comune alle transazioni di offerte, ordini, ordini aperti, consegne, resi e fatture.

Permette di modificare la finestra generata dalla transazione in particolare per cancellare un folder specifico.

Questo entry point è situato nel programma SUBSLX.

Contesto e modalità di funzionamento

Transazione

C'è una transazione in corso. La variabile GOK è utilizzata e testata. E' uguale a 1. Può essere posizionata a 0 se si desidera abbandonare la transazione.

File traccia

Non c'è file traccia aperto.

Diversi casi di chiamata

Viene chiamato nelle azioni CREATION, MODIF, ANNULE nei programmi:

-          SUBSLQ: transazioni offerte

-          SUBSLC: transazioni ordini

-          SUBSLO: transazioni ordini aperti

-          SUBSLD: transazioni consegne

-          SUBSLR: transazioni resi

-          SUBSLI: transazioni fatture

Videate disponibili

Variabili disponibili

Si dispone delle seguenti variabili per definire l'elaborazione da effettuare:

[F:SLT]STRTYP           Tipo di transazione

[F:SLT]STRNUM          Codice transazione

FOBJ                            Nome dell'oggetto ( "SQH", "SOH", "SOR", "SDH", "SIH", "SRH" )

WINREF                        Nome della finestra di riferimento

                                      ="O"+Nome dell'oggetto ( "SQH", "SOH", "SOR", "SDH", "SIH", "SRH" )

NOMWIN                       Nome della finestra generata per questa transazione

                                       ="WO"+Nome dell'oggetto+Codice transazione

Tabelle aperte 

Sono aperte le tabelle AWINDOW, AWINPAR, AREPORT, AMSK, AMSKZON, AMSKACT, ed anche tutte le tabelle necessarie alla gestione generazione delle videate e programmi.